(2012-08-31, 23:20)fr500 Wrote: Hey, I updated my steam script so it no longer kills steam, now it closes it gracefully, also now it timeouts if it can start an app without pausing XBMC, here are my scripts

These scripts pause XBMC so it's not consuming any resources while games are running. First my steam script:

All you need to do is point Advanced launcher to the script and use the Steam Id of the game you want to launch, you can find the ID by creating a steam desktop icon and checking it's properties. for it to function you need to have steam community in-game enabled as it will track for gameoverlayui.exe. Some steam IDs here.

Code:

@echo off

REM *****************************************************************************************************
REM Usage:
REM call launcher_steam with an argument that is the steamid of the game
REM ex: launcher_steam 40800
REM script will track for gameoverlayui.exe
REM *****************************************************************************************************

REM setup variables
set limit=120
set iteration=0

echo STARTING GAME
echo *******************************************************
start "GAME" "steam://rungameid/"%1
set process_1=gameoverlayui.exe
set process_2=steam.exe
set ignore_result=INFO:

timeout 30

echo CHECK IF STEAM HAS STARTED
echo *******************************************************
:0

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_2%"`) do if not %%A==%ignore_result% set var=running
echo steam %var% after %iteration% seconds
timeout 1

set /a iteration=iteration+1
if %iteration% == %limit% goto :3

if %var% == notrunning goto :0

set iteration=0

echo STEAM RUNNING CHECK IF GAME HAS STARTED
echo *******************************************************
:1

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_1%"`) do if not %%A==%ignore_result% set var=running
echo game %var% after %iteration% seconds
timeout 1

set /a iteration=iteration+1
if %iteration% == %limit% goto :5

if %var% == notrunning goto :1

echo GAME STARTED PAUSE XBMC
echo *******************************************************
pssuspend XBMC.exe


echo GAME STARTED CHECK IF GAME IS STILL RUNNING
echo *******************************************************
:2

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_1%"`) do if not %%A==%ignore_result% set var=running
echo game still %var%
timeout 5
if %var% == running goto :2

echo GAME STOPPED RESUME XBMC AND SHUTDOWN STEAM
echo *******************************************************
pssuspend -r XBMC.exe
start C:\Games\steam\steam.exe -shutdown

set limit=600
set iteration=0

echo CHECK IF STEAM IS STILL RUNNING
echo *******************************************************
:3

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_2%"`) do if not %%A==%ignore_result% set var=running
echo steam still %var%
timeout 1
set /a iteration=iteration+1
if %iteration% == %limit% goto :4
if %var% == running goto :3
exit

:4
echo STEAM DIDN'T SHUTDOWN AFTER %limit% SECONDS, KILLING IT
echo *******************************************************
taskkill /IM steam.exe /f
exit

:5
echo GAME %1 DIDN'T START OR PROCESS %2 COULDNT' BE FOUND
echo *******************************************************
echo GAME %1 DIDN'T START OR PROCESS %2 COULDNT' BE FOUND > c:\launcherlog.txt
echo SHUTDOWN STEAM
echo *******************************************************
start C:\Games\steam\steam.exe -shutdown
echo CHECK IF STEAM IS STILL RUNNING
echo *******************************************************
goto :3

The second one, a generic .lnk launcher, it will launch the game.lnk file you specify (no need to add .lnk to arguments) and will track any specific process you want it to track, remember to set the path to your launchers in the batch file itself on this line:

set launcher_path=C:\path\to\your\shortcuts\

Code:

@echo off

REM *****************************************************************************************************
REM Usage:
REM call launcher_regular with 2 arguments, first argument is the game shortcutname, second argument
REM is the name of the process that must be tracked
REM ex: launcher_regular supermeatboy supermeatboy.exe
REM *****************************************************************************************************

REM setup variables
set limit=120
set iteration=0
set launcher_path=C:\path\to\your\shortcuts\


echo STARTING GAME
echo *******************************************************
start "GAME" %launcher_path%\%1.lnk
set process_1=%2
set ignore_result=INFO:

timeout 10

echo CHECK IF GAME HAS STARTED
echo *******************************************************
:1

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_1%"`) do if not %%A==%ignore_result% set var=running
echo game %var% after %iteration% seconds
timeout 1

set /a iteration=iteration+1
if %iteration% == %limit% goto :3

if %var% == notrunning goto :1

echo GAME STARTED PAUSE XBMC
echo *******************************************************
pssuspend XBMC.exe


echo GAME STARTED CHECK IF GAME IS STILL RUNNING
echo *******************************************************
:2

set var=notrunning
for /f "usebackq" %%A in (`tasklist /nh /fi "imagename eq %process_1%"`) do if not %%A==%ignore_result% set var=running
echo game still %var%
timeout 5
if %var% == running goto :2

echo GAME STOPPED RESUME XBMC
echo *******************************************************
pssuspend -r XBMC.exe

exit

:3
echo GAME %1 DIDN'T START OR PROCESS %2 COULDNT' BE FOUND
echo *******************************************************
echo GAME %1 DIDN'T START OR PROCESS %2 COULDNT' BE FOUND > c:\launcherlog.txt
exit

Both scripts will log to c:\launcherlog.txt in case of an error, hope these are helpful

(2012-08-31, 23:20)fr500 Wrote: Hey, I updated my steam script so it no longer kills steam, now it closes it gracefully, also now it timeouts if it can start an app without pausing XBMC, here are my scripts

(2012-09-02, 18:32)Miles_prower Wrote: Hi there.

I'm trying to use this addon, and it works correctly with standalone executables, but it doesn't do anything when I try to launch emulators.

I configured the addon correctly with the emulators Kega (Sega Genesis) and Snes9X (Snes) and it doesn't do anything when I press INTRO.

Any help, please?

(2012-09-02, 21:31)Maleficium Wrote: Hi there,

It's my first experience with this addon and I'm not being able to use the GameFAQ scrapper to download the thumb (cover) from their site. All other data its being imported from their site. I'm being able to bring the thumbs from other scrappers but I think that GameFAQ its the most complete database for titles that only appeared in the japanese market.

Its some kind of bug or I'm missing something ?

(2012-09-03, 13:06)leepenny Wrote: Hello angelscry, Im having some trouble launching my dolphin emulator, ive read that I need to create a script to close xbmc and restart so have done this as suggested by your good self (http://www.gwenael.org/forum/viewtopic.php?id=272). I have set up the display as the gwenael wiki but dont know what arguments to use with the script . I'm running on linux and have had no problems with other emulators (ps1, mame) but this one has me stumped. Any available info would be most appreciated.

(2012-08-20, 18:00)Angelscry Wrote:

(2012-08-20, 06:12)one800higgins Wrote: I'm having issues with Advanced Launcher that I can't sort out. I have tried uninstalling and reinstalling, manually removing folders and reinstalling, rebooting, etc and no dice. No matter what, my Advanced Launcher does the same thing.

I added an SNES library, but I forgot to set it to scan for images and such while adding. So, I removed the library from Advanced Launcher and planned to reimport it, but with the scan set.

However, now whenever I go to set up AL, I get the following pop-up "Loading directory, retrieved 0 items" that never goes away. I can cancel, but then I can't do anything else. Selecting another menu item just results in the window closing and going back to my add-on list.

The debug log states the following:

00:05:35 T:1128 NOTICE: ERROR: Main::get_xml_source (1409) - [Errno 2] No such file or directory: 'C:\\Users\\one800higgins\\AppData\\Roaming\\XBMC\\userdata\\addon_data\\plugin.program.advanced.launcher\\launchers.xml'
00:05:35 T:1128 NOTICE: Launcher: found 0 launchers

Strange. According to your error message, Advanced Launcher is no able to access the launchers.xml files. Does the C:\\Users\\one800higgins\\AppData\\Roaming\\XBMC\\userdata\\addon_data\\plugin.program.advanced.launcher\\launchers.xml exist?

• If so, could you post here the content of this file (using pastebin service)
  
• If not, does the XBMC user have write access to the C:\\Users\\one800higgins\\AppData\\Roaming\\XBMC\\userdata\\addon_data\\plugin.program.advanced.launcher\\ folder?

Also, could you give me more information about your system? XBMC version, Windows version and Advanced Launcher version. Finally could you post here (using pastebin service) the complete xbmc.log file after the error occurs (the problem could be generated by another plugin)?

(2012-09-05, 16:25)sdsnyr94 Wrote: If I load a version of Eden (windows or Linux).. everything works. So the million dollar question is : Is Advanced Launcher not Frodo ready yet, and is there a timeframe of when it will be?

Unfortunately, I needed some of the fixes that are in the pre-frodo builds on my ION XBMCbuntu unit, and it upgraded my database... so I need to stay frodo on my Windows unit.