Force XBMC to use jpg's or MCE to use tbn's?
#1
I would like Vista Media Center to use all my thumbnails. Currently they are jpeg's saved as .tbn files to be compatible with XBMC. MCE only recognizes them if they are .jpg's though.

Other than doubling up all my poster art and having yet another supplemental file listed with my media, is there anything I can do to get XBMC or MCE to read the same pictures?
Reply
#2
well, you have the source for xbmc...
Reply
#3
Symbolic Links could be your friend

It's not a perfect answer, and they are similar to shortcuts, but will save precious disk space. They are basically 'virtual files' pointing to another file. You need NTFS for these (not FAT/32) and check the mklink command in NT/XP/Vista

In truth I suspect diskspace isn't the issue and you just like things neat and tidy! but if it space is the issue, look at symlinks
Reply
#4
Yeah, disk space for jpg's isn't a huge issue (I would guess all of them combined are less than half the size of a single movie) but either duplicating them or creating a symlink is probably what I'll end up having to do since it doesn't sound like there is an easy way to get mce to use tbn's or vice versa and I don't know how to dive into the source code of xbmc.

Besides not wanting to double up the files, just the hassle of having to remember to do it every time I get a new movie/tv show is also making me wish there was a better way to do this. Oh well. Beggars can't be choosers. Smile
Reply
#5
I do the following:


Movies\
*** Movie 1\
****** Movie 1.avi
****** Additional Content\
********* Covers, fanart collection for the movie goes here

I then have a very simple batch script that lets me drag and drop any file from the Additional Content folder and it will auto generate the folder.jpg, Movie 1.tbn, Movie 1.jpg etc in the parent folder. It only takes two drag and drops (one for the Movie Cover, and One for the fanart). It also generates the Movie 1.avi-big.jpg file for Aeon Stark too)

You're welcome to it if you like.
Reply
#6
AnalogKid Wrote:You're welcome to it if you like.
Yeah, I'll have a look at it if you don't mind. I currently don't have my movies stored in their own subfolders but I'm always interested in how others are doing it. I'm game for any way that looks like it is more organized and easier to implement.
Reply
#7
OK, I'm not sure how familar you are with Bat(ch) files... but the instructions are as follows:

- Create two textfiles - one called "Thumbs.bat" and one "Fanart.bat" (source code is included at the bottom of my post.
- The Thumbs.bat is used to create thumb artwork!
- The Fanart.bat is used to create fanart artwork!
- Place these two file ANYWHERE on your system (I tend to keep them on my desktop when I'm working with them)

OK, so now to the real instructions.

- Make sure you store your movies in the following structure

MovieName\
........MovieName.avi (or wmv etc) ;The MovieName's MUST match
........Additional Artwork\
............. (Put all your artwork for the movie in here, any filenames will do)


- Now, when you need to create the thumbs for the movie, drag a suitable image from the 'Additional Artwork' folder onto the Thumbs.bat file

- When you need to create a fanart for the movie, drag a suitable image from the 'Additional' Artwork folder on the Fanart.bat file

The bat files will take care of image renaming (and will not touch your original image files in the 'Additional Artwork' folder). They will also set the images to hidden (this is just something I prefer,but can easily be changed)



********* Source Code for Thumb.bat **************

@echo off

rem **** Set zzImageSourceFile to the file that was dropped onto the batch file (%1)
set zzImageSourceFile=%~1

rem **** Set zzMovieFolder to parent folder of the source image file.
rem **** This should then be the full path to the actual movie
cd /D %~dp1..
Set zzMovieFolder=%CD%

rem **** Set zzMovieName to the the actual name of the movie
rem **** This is calculated by moving to the movie folder
rem **** and parsing the last part of the path (the folder name) to obtain the movie name
cd /D %zzMovieFolder%
for /F "delims=\" %%I in ("%CD%") do set zzMovieName=%%~nxI


rem **** Set zzMovileFile to actual name of the movie file
rem **** This is discovered by bruteforce searching for avi, wmv files etc
if exist "%zzMovieFolder%\%zzMovieName%.avi" set zzMovieFile=%zzMovieName%.avi
if exist "%zzMovieFolder%\%zzMovieName%.wmv" set zzMovieFile=%zzMovieName%.wmv
if exist "%zzMovieFolder%\%zzMovieName%.mkv" set zzMovieFile=%zzMovieName%.mkv



echo Image File = %zzImageSourceFile%
echo Movie Folder = %zzMovieFolder%
echo Movie Name = %zzMovieName%
echo Movie File = %zzMovieFile%

if exist "%zzMovieFolder%\%zzMovieName%.tbn" attrib -H "%zzMovieFolder%\%zzMovieName%.tbn"
if exist "%zzMovieFolder%\%zzMovieFile%-big.png" attrib -H "%zzMovieFolder%\%zzMovieFile%-big.png"

copy "%zzImageSourceFile%" "%zzMovieFolder%\%zzMovieName%.tbn"
copy "%zzImageSourceFile%" "%zzMovieFolder%\%zzMovieFile%-big.png"

attrib +H "%zzMovieFolder%\%zzMovieName%.tbn"
attrib +H "%zzMovieFolder%\%zzMovieFile%-big.png"

pause






********* Source Code For Fanart.bat *******************

@echo off

rem **** Set zzImageSourceFile to the file that was dropped onto the batch file (%1)
set zzImageSourceFile=%~1

rem **** Set zzMovieFolder to parent folder of the source image file.
rem **** This should then be the full path to the actual movie
cd /D %~dp1..
Set zzMovieFolder=%CD%

rem **** Set zzMovieName to the the actual name of the movie
rem **** This is calculated by moving to the movie folder
rem **** and parsing the last part of the path (the folder name) to obtain the movie name
cd /D %zzMovieFolder%
for /F "delims=\" %%I in ("%CD%") do set zzMovieName=%%~nxI


rem **** Set zzMovileFile to actual name of the movie file
rem **** This is discovered by bruteforce searching for avi, wmv files etc
if exist "%zzMovieFolder%\%zzMovieName%.avi" set zzMovieFile=%zzMovieName%.avi
if exist "%zzMovieFolder%\%zzMovieName%.wmv" set zzMovieFile=%zzMovieName%.wmv
if exist "%zzMovieFolder%\%zzMovieName%.mkv" set zzMovieFile=%zzMovieName%.mkv



echo Image File = %zzImageSourceFile%
echo Movie Folder = %zzMovieFolder%
echo Movie Name = %zzMovieName%
echo Movie File = %zzMovieFile%



if exist "%zzMovieFolder%\%zzMovieName%-fanart.jpg" attrib -H "%zzMovieFolder%\%zzMovieName%-fanart.jpg"

copy "%zzImageSourceFile%" "%zzMovieFolder%\%zzMovieName%-fanart.jpg"

attrib +H "%zzMovieFolder%\%zzMovieName%-fanart.jpg"

pause
Reply

Logout Mark Read Team Forum Stats Members Help
Force XBMC to use jpg's or MCE to use tbn's?0