ASMUpdate won't download or install skin
#16
Does the Auriga directory exist already in both of the directories you mentioned at the start of the thread? Do those directories exist?

Maybe remove the Auriga directories and try again?
Reply
#17
No Auriga directories at all.

I am using Windows 7, if that makes a difference somehow.

The readme told me not to install in Program Files, and I didn't

Anything else?

This is really starting to bug me. Could somehow the script have the repository address wrong? Can I check this?

But the thing is that the GIT does not even start when I choose Auriga. With Showmix it does.
Reply
#18
I got this from the ASMUpdate batch file:

rem ---- Aeon Auriga ----
if defined GETAURIGA (
call :SKINUPDATE "Aeon Auriga" AAGIT git://github.com/djh/aeon.git origin/auriga 1
)


Can you please check if you have the same?
Reply
#19
I don't see that at all in my batch file...are you using the latest version of ASMUpdate?
Reply
#20
http://pastebin.com/m2bb8d82e

Here is my batch file
Reply
#21
Yours seems to be an older, but working version. 20090818

I have 20091006
Reply
#22
give mine a try and see if it works on your system
Reply
#23
No Sad

It the ASMUpdate just shuts off in less than a second. The other files in the folder might be different.
Reply
#24
I would recommend you open up a DOS prompt and run the batch file from inside that. That way it won't close the window on you and you see where the error is.
Reply
#25
It says:
"0 was unexpected at this time"

Huh
Reply
#26
ASM Update Code
Code:
@echo off

rem ---- _NO_USER_CONFIGURABLE_OPTIONS_BELOW_ ----
rem ---- Set Configuration in ASMConfig.bat ----
rem ---- File: ASMUpdate.bat, Ver: 20091006 ----

rem ---- Configure ----
setlocal
call ASMConfig.bat

rem ---- Launch XBMC Update ----
call :XBMCUPDATE

rem ---- Configure GIT Environment Variables ----
set PLINK_PROTOCOL=ssh
set path=%GITPATH%;%PATH%

rem ---- Aeon Showmix ----
if defined GETSHOWMIX (
    call :SKINUPDATE "Aeon Showmix" ASMGIT git://github.com/andyblac/aeon.git origin/master 0
)
if %ERRFLAG% NEQ 0 (goto END)

rem ---- Aeon Auriga ----
if defined GETAURIGA (
    call :SKINUPDATE "Aeon Auriga" AAGIT git://github.com/djh/aeon.git origin/auriga 1
)
if %ERRFLAG% NEQ 0 (goto END)

rem ---- Aeon Hitched ----
if defined GETHITCHED (
    call :SKINUPDATE "Aeon Hitched" AHMGIT git://github.com/Hitcher/aeon.git origin/master 1
)
if %ERRFLAG% NEQ 0 (goto END)

rem ---- Aeon Phil65 ----
if defined GETPHIL65 (
    call :SKINUPDATE "Aeon Phil65" APMGIT git://github.com/temmi2000/aeon.git origin/master 1
)
if %ERRFLAG% NEQ 0 (goto END)

rem ---- End ----
:END
endlocal
echo.
goto :EOF

rem ---- XBMC Update ----
rem call :XBMCUPDATE
:XBMCUPDATE
if not exist xbmcupdate\xbmcupdate.config (goto :EOF)
start xbmcupdate\xbmcupdate.exe /update
goto :EOF

rem ---- Print Error Message ----
rem call :ERRORMSG <error-message>
:ERRORMSG
echo.
echo ERROR: %~1
echo.
pause
goto :EOF

rem ---- Git Pull (Update) ----
rem call :GITPULL <skin-name> <tmpfolder> <git-tree>
:GITPULL
echo.
cd %~2
git fetch -v
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Executing Git Pull for %~1" & goto :EOF)
git checkout -f %~3
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Executing Git Checkout for %~1" & goto :EOF)
cd ..
goto :EOF

rem ---- Git Clone (Get) ----
rem call :GITCLONE <skin-name> <tmpfolder> <git-url> <git-tree>
:GITCLONE
git clone --depth 1 %~3 %~2
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Excecuting Git Clone for %~1" & goto :EOF)
cd %~2
git checkout -f %~4
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Excecuting Git Checkout for %~1" & goto :EOF)
git branch -D master
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Excecuting Git Branch for %~1" & goto :EOF)
cd ..
goto :EOF

rem ---- Copy Skin to XBMC Folder ----
rem call :CPSKIN <skin-name> <tmpfolder> <extra-fonts?>
:CPSKIN
echo.
if not defined XBMCFOLDER (goto :EOF)
if not exist %XBMCFOLDER% (goto :EOF)
if not exist %~2\skin.xml (goto :EOF)
rem Comment the next line to _NOT_ force overwrites
rd /s /q %XBMCFOLDER%\"%~1"
mkdir %XBMCFOLDER%\"%~1"
cd %~2
for /f "usebackq delims=" %%i in (`dir /ad /b`) do if "%%i" NEQ ".git" (xcopy "%%i" %XBMCFOLDER%\"%~1"\"%%i" /s /e /i /y)
for /f "usebackq delims=" %%i in (`dir /a-d /b`) do if "%%i" NEQ ".gitignore" (copy "%%i" %XBMCFOLDER%\"%~1"\"%%i" /y)
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Copying %~1 Skin Files" & goto :EOF)
for /f "usebackq delims=" %%i in (`dir /ad /b`) do if "%%i" NEQ ".git" (rd /s /q "%%i")
for /f "usebackq delims=" %%i in (`dir /a-d /b`) do if "%%i" NEQ ".gitignore" (del /q "%%i")
cd ..
xcopy fonts %XBMCFOLDER%\"%~1"\fonts /s /e /i /y
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Copying %~1 Skin Fonts" & goto :EOF)
if %~3 NEQ 0 (xcopy fonts.extra\* %XBMCFOLDER%\"%~1"\fonts /s /e /i /y)
if %ERRORLEVEL% NEQ 0 (set ERRFLAG=1 & call :ERRORMSG "Error Copying %~1 Skin Fonts Extra" & goto :EOF)
goto :EOF

rem ---- Skin Update ----
rem call :SKINUPDATE <skin-name> <tmpfolder> <git-url> <git-tree> <extra-fonts?>
:SKINUPDATE
set ERRFLAG=0
if not exist %~2 (
    call :GITCLONE "%~1" "%~2" "%~3" "%~4"
) else (
    call :GITPULL  "%~1" "%~2" "%~4"
)
if %ERRFLAG% NEQ 0 (goto :EOF)
call :CPSKIN  "%~1" "%~2" "%~5"
if %ERRFLAG% NEQ 0 (goto :EOF)
goto :EOF
Reply
#27
ASMConfig Code
Code:
@echo off

rem ---- EDIT THIS FILE FOR WINDOWS PLATFORM ----
rem Script Version: 20091006, Patrick Khoo

rem ---- Step 1: Configure Path to XBMC Skins Folder ----
rem Comment the line below with "rem" if you want/need to (Git) update your skins folder manually
rem or if you just want to keep a local Git copy of Aeon Skin/Mod(s) up-to-date outside XBMC
set XBMCFOLDER="C:\Program Files\XBMC\skin"

rem ---- Step 2: Choose the Skin You Want ----
rem Uncomment One/All of the below lines to download the Aeon Skin/Mod(s) as Required
rem * Aeon Showmix (by andyblac)
rem set GETSHOWMIX=1
rem * Aeon Auriga (by djh)
set GETAURIGA=1
rem * Aeon Hitched (by hitcher)
rem set GETHITCHED=1
rem * Aeon Phil65 (by temmi2000)
rem set GETPHIL65=1

rem ---- Step 3: (If Needed) Configure Path to Git ----
rem Path to Git - Use Included Stripped Down Git, or Provide Your Own
set GITPATH=%~dp0\git
rem If you are using your own Git, try something like:
rem set GITPATH="C:\Program Files\Git"
Reply
#28
thats all it saidHuh Oo

can you paste everything after you ran the command?

can you paste your entire batch file?
Reply
#29
Actually I had to rem to the echo. Then it said more.
I have never learnt coding but figured it out. Quite proud and a little embarrassed. LOL

Here is what ASMUpdate.bat says when I execute it:
Code:
C:\Program Files\ASMUpdate>rem @echo off

C:\Program Files\ASMUpdate>rem ---- _NO_USER_CONFIGURABLE_OPTIONS_BELOW_ ----

C:\Program Files\ASMUpdate>rem ---- Set Configuration in ASMConfig.bat ----

C:\Program Files\ASMUpdate>rem ---- File: ASMUpdate.bat, Ver: 20091006 ----

C:\Program Files\ASMUpdate>rem ---- Configure ----

C:\Program Files\ASMUpdate>setlocal

C:\Program Files\ASMUpdate>call ASMConfig.bat

C:\Program Files\ASMUpdate>rem @echo off

C:\Program Files\ASMUpdate>rem ---- EDIT THIS FILE FOR WINDOWS PLATFORM ----

C:\Program Files\ASMUpdate>rem Script Version: 20091006, Patrick Khoo

C:\Program Files\ASMUpdate>rem ---- Step 1: Configure Path to XBMC Skins Folder
----

C:\Program Files\ASMUpdate>rem Comment the line below with "rem" if you want/nee
d to (Git) update your skins folder manually

C:\Program Files\ASMUpdate>rem or if you just want to keep a local Git copy of A
eon Skin/Mod(s) up-to-date outside XBMC

C:\Program Files\ASMUpdate>set XBMCFOLDER="C:\Program Files\XBMC\skin"

C:\Program Files\ASMUpdate>rem ---- Step 2: Choose the Skin You Want ----

C:\Program Files\ASMUpdate>rem Uncomment One/All of the below lines to download
the Aeon Skin/Mod(s) as Required

C:\Program Files\ASMUpdate>rem * Aeon Showmix (by andyblac)

C:\Program Files\ASMUpdate>rem set GETSHOWMIX=1

C:\Program Files\ASMUpdate>rem * Aeon Auriga (by djh)

C:\Program Files\ASMUpdate>set GETAURIGA=1

C:\Program Files\ASMUpdate>rem * Aeon Hitched (by hitcher)

C:\Program Files\ASMUpdate>rem set GETHITCHED=1

C:\Program Files\ASMUpdate>rem * Aeon Phil65 (by temmi2000)

C:\Program Files\ASMUpdate>rem set GETPHIL65=1

C:\Program Files\ASMUpdate>rem ---- Step 3: (If Needed) Configure Path to Git --
--

C:\Program Files\ASMUpdate>rem Path to Git - Use Included Stripped Down Git, or
Provide Your Own

C:\Program Files\ASMUpdate>set GITPATH=C:\Program Files\ASMUpdate\\git

C:\Program Files\ASMUpdate>rem If you are using your own Git, try something like
:

C:\Program Files\ASMUpdate>rem set GITPATH="C:\Program Files\Git"

C:\Program Files\ASMUpdate>rem ---- Launch XBMC Update ----

C:\Program Files\ASMUpdate>call :XBMCUPDATE

C:\Program Files\ASMUpdate>if not exist xbmcupdate\xbmcupdate.config (goto :EOF
)

C:\Program Files\ASMUpdate>start xbmcupdate\xbmcupdate.exe /update

C:\Program Files\ASMUpdate>goto :EOF

C:\Program Files\ASMUpdate>rem ---- Configure GIT Environment Variables ----

C:\Program Files\ASMUpdate>set PLINK_PROTOCOL=ssh

C:\Program Files\ASMUpdate>set path=C:\Program Files\ASMUpdate\\git;C:\Program F
iles\Common Files\Microsoft Shared\Windows Live;C:\Windows\system32;C:\Windows;C
:\Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program F
iles\QuickTime\QTSystem\;C:\Program Files\Common Files\Microsoft Shared\Windows
Live

C:\Program Files\ASMUpdate>rem ---- Aeon Showmix ----

C:\Program Files\ASMUpdate>if defined GETSHOWMIX (call :SKINUPDATE "Aeon Showmix
" ASMGIT git://github.com/andyblac/aeon.git origin/master 0 )
0 was unexpected at this time.

C:\Program Files\ASMUpdate>if  NEQ 0 (goto END)

C:\Program Files\ASMUpdate>
Reply
#30
what fixed it? removing the 0 on

(call :SKINUPDATE "Aeon Showmix
" ASMGIT git://github.com/andyblac/aeon.git origin/master 0 )

?
Reply

Logout Mark Read Team Forum Stats Members Help
ASMUpdate won't download or install skin0