[trogggy]

Hacky solution:
You could try using a batch file to check your network is up, then start kodi when it is.
I have something similar that I use in a restart script that's easily adapted.  You're welcome to try it.
Assuming kodi's in the usual place:

@echo OFF

rem check if kodi's already running
tasklist | find /i "kodi" >nul 2>&1
rem start kodi when network's up
IF ERRORLEVEL 1 (
  ECHO Kodi is not running
  GOTO CONTINUE
) ELSE (
  ECHO Kodi is already running
  PAUSE
  EXIT
)
:CONTINUE
rem check if internet connected.  If not, wait  / loop
echo checking internet connection
:LOOP
Ping www.google.nl -n 1 -w 1000
cls
IF ERRORLEVEL 1 (
  ECHO No internet detected.
  ECHO Hang on a tick
  Timeout /T 2 /Nobreak
  GOTO LOOP
) ELSE (
  GOTO STARTKODI
)
:STARTKODI
START "" "C:\Program Files\Kodi\kodi.exe"

Change the path to kodi.exe if necessary.  Open a text editor, copy and paste the above into it, save as eg 'startkodi.bat' (make sure it's not startkodi.bat.txt'!).
Double-click the file.
It should start kodi if your network's up.
If you have no network (actually internet) it will wait.

This assumes you're not using the windows store version btw.