[z-vap]

Okay this is how I do it.

Install autohotkey on any pc (doesn't have to be the htpc).
Download SysInternals.
Extract pssuspend.exe. Copy it to the HTPC, and run it once, as the htpc user. This sets the SysInternals EULA.

Copy these three programs to the indicated text files, and compile them using Autohotkey:

XBMCAppHandler.ahk

Code:

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win9x/NT
; Author:         Joe Christl
;
; Script Function:
;    Program Launcher for XBMC
;

#SingleInstance force
SetTitleMatchMode, 2
#WinActivateForce

pCount = %0%
Loop %pCount%
  Param%A_Index% := %A_Index%


Start:
Sleep, 100
WinHide, XBMC
Sleep, 100
RunWait, %comspec% /c "pssuspend xbmc.exe"  ,,hide
Sleep, 100


Run, %Param1% %Param2% %Param3% %Param4% %Param5% %Param6% %Param7% %Param8% %Param9% %Param10% ,, Max

;======================================================
Sleep, 5000

NeedleRegEx = i)^.*\\
FoundPos := RegExMatch(param1, NeedleRegEx, RegPID )
StringReplace, NewPID, param1, %RegPID%

Process, Exist, %NewPID%
Process, WaitClose, %NewPID%

Process, Exist, XBMC.exe
XPid = %ErrorLevel%

Sleep, 500
RunWait, %comspec% /c "pssuspend -r xbmc.exe"  ,,hide
Sleep, 100
WinShow, ahk_pid %XPid%

WinActivate, ahk_pid %XPid%

ExitApp


#IfWinActive ahk_class eHome Render Window
Esc::
Send !{F4}
return
#IfWinActive

ShowIconsTask.ahk

Code:

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win9x/NT
; Author:         Joe Christl
;
; Script Function:
;    Shows taskbar and icons
;

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


; show icons and taskbar
WinExist("ahk_class Progman")
Control, Show,, SysListView321
WinExist("ahk_class WorkerW")
Control, Show,, SysListView321
WinShow,ahk_class Shell_TrayWnd
WinShow,Start ahk_class Button

HideIconsTask.ahk

Code:

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win9x/NT
; Author:         Joe Christl
;
; Script Function:
;    Hides taskbar and icons
;

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

; hide icons and taskbar
WinExist("ahk_class Progman")
Control, Hide,, SysListView321
WinExist("ahk_class WorkerW")
Control, Hide,, SysListView321
WinHide,ahk_class Shell_TrayWnd
WinHide,Start ahk_class Button

Take the shortcuts from the first post, and prepend to the target the fully qualified path to where you're putting the XBMCAppHandler.exe. I recommend enclosing the first two executables inside quotes "
Ex.

Code:

StartMCELiveTV.lnk
"C:\Users\Public\Documents\XBMCAppHandler.exe" "%windir%\ehome\ehshell.exe" /nostartupanimation /homepage:VideoFullscreen.xml /PushStartPage:True

StartMCENetflix.lnk
"C:\Users\Public\Documents\XBMCAppHandler.exe" "%windir%\ehome\ehshell.exe" /url:windowsmediacenterapp:{e6f46126-f8a9-4a97-9159-b70b07890112}\{982ea9d3-915c-4713-a3c8-99a4688b7c59}?EntryPointParameters=

StartMCETRecordedTV.lnk
"C:\Users\Public\Documents\XBMCAppHandler.exe" "%windir%\ehome\ehshell.exe" /nostartupanimation /homepage:RecordedTV.BrowsePage.xml /PushStartPage:True

StartMCETScheduled Recordings.lnk
"C:\Users\Public\Documents\XBMCAppHandler.exe" "%windir%\ehome\ehshell.exe" /nostartupanimation /homepage:VideoToBeRecorded.xml /PushStartPage:True

StartMCETVGuide.lnk
"C:\Users\Public\Documents\XBMCAppHandler.exe" "%windir%\ehome\ehshell.exe" /nostartupanimation /homepage:VideoGuide.xml /PushStartPage:True

Place ShowIconTask.exe and HideIconTask.exe on the desktop. Make sure XBMCAppHandler.exe, pssuspend.exe and the links are all in the same directory.

Use AdvLauncher to add the links to xbmc. I then re-edit each launcher and go into Advanced and turn off Toggle fullscreen.

Find a cool background. I chose this one = http://www.htbackdrops.com/v2/displayima...?pid=15738

Run HideiconsTask.exe to hide your taskbar and icons. If for some reason you need to get to your icons or taskbar, simply use your mouse to right-click and toggle View > Show desktop icons once or twice. Then you can run ShowIconsTask.exe

You won't need EsctoClose.exe anymore as that functionality is now integrated.

Enjoy. Thanks to Zellig for the idea.

Extra: if you're feeling jumpy, try using this to hide your extra windows media strips. Be careful as I have only used it in testing.